Hi Thomas,

To upload it from Powerbuilder you just need to code it as a multipart form upload.  There are a few posts on the forum about how to do it, but here is a simple example without any validation.  For this particular example it's a multipart form with a single part.

long ll_FileNum
blob blb_file
blob blb_boundary
blob blb_terminus
blob blb_multipart
integer li_rc
HTTPClient lnv_HttpClient

string ls_endpoint
string ls_file
integer li_ResponseStatusCode = 0
string ls_ResponseBody = ''
string ls_ResponseStatusMessage = ''


// Hard code the file name and endpoint for testing
ls_file = 'c:\temp\invoice.pdf'
ls_endpoint = 'http://localhost:5000/api/file/upload'

// Create a boundary marker for the multipart blob
string ls_Boundary = "$$$Boundary$$$"

// Read the file into a blob
ll_FileNum = FileOpen(ls_file, StreamMode!)
if ll_FileNum > 0 then
    FileReadEx(ll_FileNum, blb_file)
    FileClose(ll_FileNum)
else
    MessageBox('File Error',  'Error Opening Filename ' + ls_file)
    return
end if

// Create component blobs
blb_boundary = blob('~r~n--' + ls_Boundary + '~r~n', EncodingUTF8!)
blb_file = blob( 'Content-Disposition: form-data; name="uploadedFile"; filename="invoice.pdf"~r~n' + &
                        "Content-Type: application/pdf~r~n~r~n", EncodingUTF8!) + &
                        blb_file
blb_terminus = blob('~r~n--' + ls_Boundary + '--~r~n', EncodingUTF8!)

// Concatenate blobs into a single multipart blob
blb_multipart = blb_boundary + blb_file + blb_terminus

// Send the request
lnv_HttpClient = create HTTPClient
lnv_httpClient.SetRequestHeader("Content-Type", "multipart/form-data; boundary=" + ls_BOUNDARY)

li_rc = lnv_httpClient.SendRequest('POST', ls_endpoint, blb_multipart)

// obtain the response data
if li_rc = 1 then
    li_ResponseStatusCode = lnv_HttpClient.GetResponseStatusCode()
    ls_ResponseStatusMessage = lnv_HttpClient.GetResponseStatusText()
    lnv_HttpClient.GetResponseBody(ls_ResponseBody, EncodingUTF8!)

    if li_ResponseStatusCode = 200 then
        MessageBox('Upload Successfull', ls_ResponseBody)
    else
        MessageBox('Upload Failed', ls_ResponseBody)
    end if
else
    MessageBox('HTTP Error', 'Error calling ' + ls_endpoint + '.  Return Code ' + string(li_rc))
end if

Daryl, 

I've added FileController.cs to my SnapDevelop API and it works when I use it with Swagger.  I'm having a hard time calling this from a PowerBuilder client app however.  I'm using GetFileOpenName() to select a file (PDF) but am not quite sure how to pass it to the controller via restclient or httpclient.  Do you have any sample code that you can share that illustrates how this could be done?

Thanks, Tom 

Hi Lingaiah, are you writing the API that clients will call to upload and download files?

e.g, with endpoints (controllers) similar to these:

https://my.webserver.com/api/download

https://my.webserver.com/api/upload

or are you trying to call an API from your C# that will upload and download files?

Hi Lingiah;

   SNAP is just plain C#, so you can just use the .Net frameworks FTP API. Here is the download API example. For PB, just create a .Net Assembly with that code. The new PB 2019 R2 can then consume the Assembly directly in this release.

HTH

Regards... Chris