Hi John,

The easiest way would be to just use the HttpClient.  Here is an example of how you could do it.  It's just thrown together so hasn't been tested thoroughly, but it will give you an idea.

HttpClient lnv_HttpClient
string ls_url
string ls_error
string ls_data = ''
string ls_responsetext = ''
integer li_rc
integer li_response

ls_url = 'http://data.iana.org/TLD/tlds-alpha-by-domain.txt'

lnv_HttpClient = Create HttpClient

lnv_HttpClient.SetRequestHeader('Accept', '*/*')

li_rc = lnv_HttpClient.SendRequest('GET', ls_url)

if li_rc = 1 then
	li_response = lnv_HttpClient.GetResponseStatusCode()

	if li_response = 200 then
		// The response was ok, so read the filecontents into ls_data
		li_rc = lnv_HttpClient.GetResponseBody(ls_data)
		if li_rc = 1 then
			// You would probably call a function to import the data at this stage,
			// but I've got code down below to import as an example
		else
			ls_error = 'Error getting response body for OAuth.  Return Code ' + string(li_rc)
		end if
	else
		ls_responsetext = lnv_HttpClient.GetResponseStatusText()
		ls_error = 'Error getting response~r~n' + string(li_response) + ' ' + ls_responsetext
	end if
else
	ls_error = 'Error retrieving URL ' + ls_url + ' - Return Code ' + string(li_rc)
end if

destroy lnv_HttpClient


// You can do this bit however you want, but just as an example I'll import it into a dynamic datastore
// This code would most likely be in it's own function and called from above

if ls_data <> '' then
	string ls_syntax
	datastore lds_tld
	ls_syntax = SQLCA.SyntaxFromSQL('select tld = convert(char(500), null)', 'Style(Type=Tabular)', ls_error)
	
	if Len(ls_error) = 0 then
		lds_tld = create datastore
	
		lds_tld.Create(ls_syntax, ls_error)
		
		if ls_error = '' then
			li_rc = lds_tld.ImportString(Text!, ls_data)
			
			if li_rc > 0 then
				// Display a few messages to show that it worked
				MessageBox('Debug', 'Imported ' + string(li_rc) + ' rows')
				MessageBox('Debug', lds_tld.GetItemString(1, 'tld'))
				MessageBox('Debug', lds_tld.GetItemString(li_rc, 'tld'))
			else
				ls_error = 'Error importing data. Return Code ' + string(li_rc)
			end if
		end if
	end if
end if