You should try to catch OLERuntimeError exception. It contains a property "description" that may have additional information about the error.

Hi,

Please read the first post on this Q&A to paste code. It's very hard to read your code like this and it really disencourages people to try and decifer it to give you any help: https://community.appeon.com/index.php/qna/q-a/q-a-forum-tip-including-source-code-in-your-question 

I think the problem is your for loop. ll_i (my example below) will always be one higher that maximum of the "to" of the for loop:

I you do this for example:

long ll_i

for ll_i = 1 to 10
	// do nothing
next

// ll_i will be 11, not 10 !!!
messagebox('debug', ll_i)

So in other words, after your loop, it looks like you might expect li_work to be equal to li_works, but it's not, it's higher: "li_works + 1":

FOR li_work = 1 TO li_works
    ls_workBook_name = Upper( lole_excel.Application.workBooks(li_work).Name )
    IF ls_workBook_name = Upper( ls_fileName[ li_file ] ) THEN
        EXIT
    END IF
NEXT

IF li_work > li_works THEN
    .....

li_work will always be greater than li_works, but won't point anything valid in Excel.

Okay, I see what you about li_work.

First to make your code readable:

// More code before this 


li_connect_excel = lole_excel.ConnectToObject( ls_source_file )

IF li_connect_excel < RET_OK THEN
	Parent.plb_filesToLoad.deleteItem( li_file )
	Parent.plb_filesToLoad.insertItem( ls_source_file, IMA_FILE_FAIL, li_file )
	ls_message = wfs_errorText( li_connect_excel )
	Yield()
	MessageBox( 'Export Error', 'Unable to open/load spreadsheet' + NEW_LINE + ls_source_file + NEW_LINE + ls_message + NEW_LINE + 'Please check if the file is open by another process.' )
	wf_checkAcceptVisible()
	This.pictureName = '..\Img\bt_apply.png'
	This.enabled = True
	w_loadFile.pb_prior.enabled = True
	wf_setTabsStatus( True )
	EXIT
END IF

li_works = lole_excel.Application.workBooks.Count

FOR li_work = 1 TO li_works
	ls_workBook_name = Upper( lole_excel.Application.workBooks(li_work).Name )
	IF ls_workBook_name = Upper( ls_fileName[ li_file ] ) THEN
		EXIT
	END IF
NEXT

IF li_work > li_works THEN
	Parent.plb_filesToLoad.deleteItem( li_file )
	Parent.plb_filesToLoad.insertItem( ls_source_file, IMA_FILE_FAIL, li_file )
	Yield()
	MessageBox( 'Export Error', 'Unable to find ' + NEW_LINE + ls_source_file + NEW_LINE + 'Please check if the file is open by another process.' )
	wf_checkAcceptVisible()
	This.pictureName = '..\Img\bt_apply.png'
	This.enabled = True
	w_loadFile.pb_prior.enabled = True
	wf_setTabsStatus( True )
	EXIT
END IF

ll_fileLength = FileLength( ls_target_file )

IF ll_fileLength <> FILE_ERROR THEN

	IF NOT FileDelete( ls_target_file ) THEN
		Parent.plb_filesToLoad.deleteItem( li_file )
		Parent.plb_filesToLoad.insertItem( ls_source_file, IMA_FILE_FAIL, li_file )
		Yield()
		MessageBox( 'Export Error', 'Unable to delete file ' + NEW_LINE + ls_target_file + NEW_LINE + 'Please check if the file is open by another process.' )
		wf_checkAcceptVisible()
		This.pictureName = '..\Img\bt_apply.png'
		This.enabled = True
		w_loadFile.pb_prior.enabled = True
		wf_setTabsStatus( True )
		EXIT
	END IF

END IF

li_sheet_number = li_sheet_numbers[ li_file ]
IF li_sheet_number = POS_NO_POSITION THEN
	li_sheet_number = POS_FIRST
END IF

FOR li_column = 1 TO li_columns[ li_file ]
	lole_excel.Application.workBooks(li_work).workSheets(li_sheet_number).Columns( li_column ).Replace( Char(10), '' )
NEXT

TRY

	lole_excel.Application.workBooks(li_work).workSheets(li_sheet_number).SaveAs( ls_target_file, EXCEL_xlCSV )   // Line 193

// EXCEL_xlCSV = 6

CATCH ( runtimeerror er )
	MessageBox( gnvo_app.is_appName + ' Runtime Error' &
	, er.GetMessage() + NEW_LINE + NEW_LINE + 'Contact with Tech department' &
	, StopSign! )
	wf_checkAcceptVisible()
	This.pictureName = '..\Img\bt_apply.png'
	This.enabled = True
	w_loadFile.pb_prior.enabled = True
	wf_setTabsStatus( True )
	lb_exit = True
	Parent.plb_filesToLoad.deleteItem( li_file )
	Parent.plb_filesToLoad.insertItem( ls_target_file, IMA_FILE_FAIL, li_file )

FINALLY
	lole_excel.Application.DisplayAlerts = False
	lole_excel.Application.workBooks(li_work).Close()

END TRY

// More code after this 

You say it fails on "some" machines. Do they all have write access to the drive / folder where you're trying to do the SaveAs() to?

I find it very weird that Ren'e's suggestion of doing a Catch with OLERuntimeError doesn't give you more information.

What's to see in the windows Event Viewer?

regards

Hi again,

On the PC of a user with the problem:

What happens if you use excel itself to open one of the failing sheets and then try to do a SaveAs with CSV format?

Maybe there's some kind of prompt from excel.

Here's some of my code. I seem to remember that "DisplayAlerts" has to be FALSE:

aole_xlApp.DisplayAlerts = FALSE

try
	if FileExists(as_path) then
		FileDelete(as_path)
	end if
	aole_xlApp.ActiveWorkBook.SaveAs(as_path, li_saveType)
catch (oleruntimeError oe)
	messagebox('OleError', oe.GetMessage())
	return
end try

aole_xlApp.DisplayAlerts = TRUE

Set your

lole_excel.Application.DisplayAlerts = FALSE

Try to do the SaveAs again and after the SaveAs, set it to TRUE again.

Finally the mistery was resolved... I don't know if cut my veins or leave them long as the hair!! hahaha

The folder where I did try to save the file doesn't exists, only create it, and "le voila" the application works without problem.

Obviously, the machines, users, environments where the folder exists, no problem.

Miguel, René and Chris, thank you so much for your contributions for clarify the issue.

A true pleasure.