PFC Resize Service enhancement to remove requirement to use of_SetOrigSize()

			PBUs		Pixels
Attribute		 W	  H	 W	 H
------------		--	---	--	--
titlebar		 0	 72	 0	18
menuname		 0	 64	 0	16
hscrollbar		 0	 76	 0	19
vscrollbar		72	  0	16	 0
resizable		27	 24	 6	 6
border			 9	  8	 2	 2
clientedge		18	 16	 4	 4
palettewindow		 0	-12	 0	-3

//////////////////////////////////////////////////////////////////////////////
//	Public Function:  of_SetResize
//	Arguments:	ab_switch	starts/stops the window resize service
//	Returns:	Integer		1 = success,  0 = no action necessary, -1 error
//	Description:	Starts or stops the window resize service
//////////////////////////////////////////////////////////////////////////////
//	Rev. History:	Version
//			5.0   Initial version
//			8.0   Modified to initially set window dimensions based on the class definition
//			2022  Jim Reese Modified to handle original window sizes based on painter and window properties that affect size
//////////////////////////////////////////////////////////////////////////////
Integer	li_width_offset, li_height_offset, li_found_property //JRR offset values in pixels, convert final sums to PBUs
integer	li_rc, li_v, li_vars
integer li_origwidth, li_origheight

// Check arguments
if IsNull (ab_switch) then
	return -1
end if

if ab_Switch then
	if IsNull(inv_resize) Or not IsValid (inv_resize) then
		inv_resize = create n_cst_resize
		
		/*  Get this window's class definition and extract the width and height  */
		classdefinition lcd_class
		lcd_class = this.ClassDefinition

		li_vars = UpperBound ( lcd_class.VariableList )
		For li_v = 1 to li_vars
			//JRR BEGIN window size varies from painter based on the following attributes. This adjust(s) based on which are set
			CHOOSE CASE lcd_class.VariableList[li_v].Name
				CASE "width"
					li_found_property ++ 
					li_origwidth = Integer ( lcd_class.VariableList[li_v].InitialValue ) 
				CASE "height"
					li_found_property ++
					li_origheight = Integer ( lcd_class.VariableList[li_v].InitialValue ) 
				CASE "titlebar"
					li_found_property ++
					IF lcd_class.VariableList[li_v].InitialValue THEN
						li_height_offset += 18 //72 use pixels for offsets, then convert total number to PBUs at end
					END IF
				CASE "menuname"
					li_found_property ++
					IF len(trim(string(lcd_class.VariableList[li_v].InitialValue))) > 0 THEN
						li_height_offset += 19 //76
					END IF
				CASE "hscrollbar"
					li_found_property ++
					IF lcd_class.VariableList[li_v].InitialValue THEN
						li_height_offset += 19 //76
					END IF
				CASE "vscrollbar"
					li_found_property ++
					IF lcd_class.VariableList[li_v].InitialValue THEN
						li_width_offset += 16 //72
					END IF
				CASE "resizable"
					li_found_property ++
					IF lcd_class.VariableList[li_v].InitialValue THEN
						li_width_offset += 6 //28 
						li_height_offset += 6 //24 
					END IF
				CASE "border"	
					li_found_property ++
					IF lcd_class.VariableList[li_v].InitialValue THEN
						li_width_offset += 2 //9 
						li_height_offset += 2 // 8 
					END IF
				CASE "clientedge"
					li_found_property ++
					IF lcd_class.VariableList[li_v].InitialValue THEN
						li_width_offset += 4 //18
						li_height_offset += 4 //16
					END IF
				CASE "palettewindow"
					li_found_property ++
					IF lcd_class.VariableList[li_v].InitialValue THEN
						li_height_offset -= 3 //12 //reduces height of titlebar
					END IF
			END CHOOSE
			If li_found_property = 10 Then Exit	//exit loop once all 10 values found
			//JRR END
		Next
		li_origwidth -= pixelstounits(li_width_offset,XPixelsToUnits!)   //JRR reduce orig by the offset to get back to painter values
		li_origheight -= pixelstounits(li_height_offset,YPixelsToUnits!) //JRR reduce orig by the offset to get back to painter values
		inv_resize.of_SetOrigSize ( li_origwidth, li_origheight )
	end if
else
	if IsValid (inv_resize) then
		destroy inv_resize
		li_rc = 1
	end if
end If

return li_rc